/*
  State change detection (edge detection)

  Gyakran nem kell folyamatosan tudnod a digitális bemenet állapotát, de csak azt kell
  tudni, hogy a bemenet mikor vált egyik állapotból a másikba.
  Például tudni szeretné, hogy egy gomb mikor vált KI állásból BE állapotba. Ezt
  állapotváltozás észlelésnek vagy élérzékelésnek nevezik.

  Ez a példa bemutatja, hogyan észlelhető, ha egy gomb ki-be, illetve be-ki kapcsol.

  Az áramkör:
  - nyomógomb +5V-ról a 2-es kivezetésre csatlakoztatva
  - 10 kohm-os ellenállás a 2-es kivezetésről a földre csatlakoztatva
  - LED a 13-as kivezetéstől a földig 220 ohmos ellenálláson keresztül
    (vagy használja a legtöbb Arduino kártyára beépített LED-et)

  created  27 Sep 2005
  modified 30 Aug 2011
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/digital/StateChangeDetection
*/

// ezek az állandók nem változnak:
const int  buttonPin = 2;    // a nyomógomb kivezetés száma
const int ledPin = 13;       // a LED kivezetés száma

// Variables will change:
int buttonPushCounter = 0;   // a gombnyomások számának számlálója
int buttonState = 0;         // a gomb aktuális állapota
int lastButtonState = 0;     // a gomb előző állapota

void setup() {
  // inicializálja a nyomógomb kivezetést bemenetként:
  pinMode(buttonPin, INPUT);
  // inicializálja a LED kivezetést kimenetként:
  pinMode(ledPin, OUTPUT);
  // inicializálja a soros kommunikációt:
  Serial.begin(9600);
}


void loop() {
  // olvassa el a nyomógomb beviteli kivezetését:
  buttonState = digitalRead(buttonPin);

  // összehasonlítja a buttonState-et az előző állapottal
  if (buttonState != lastButtonState) {
    // ha az állapot megváltozott, növeljük a számlálót
    if (buttonState == HIGH) {
      // ha az aktuális állapot HIGH akkor a gomb ki-ről be-re váltott:
      buttonPushCounter++;
      Serial.println("on");
      Serial.print("number of button pushes: ");
      Serial.println(buttonPushCounter);
    } else {
      // ha az aktuális állapot LOW akkor a gomb be-ről ki-re váltott:
      Serial.println("off");
    }
    // Késleltessen egy kicsit, hogy elkerülje a pergést
    delay(50);
  }
  // mentse el az aktuális állapotot utolsó állapotként, ez lesz a ciklusban következő alkalommal
  lastButtonState = buttonState;


  // négy gombnyomásonként bekapcsolja a LED-et a gombnyomás-számláló
  // maradékának ellenőrzésével. a maradék függvény megadja
  // a két szám osztásának maradékát:
  if (buttonPushCounter % 4 == 0) {
    digitalWrite(ledPin, HIGH);
  } else {
    digitalWrite(ledPin, LOW);
  }

}