/*
  Row-Column Scanning an 8x8 LED matrix with X-Y input

  Ez a példa egy 8x8 LED-es mátrixot vezérel két analóg bemenet használatával.

  Ez a példa a Lumex LDM-24488NI mátrixra vonatkozik. Lásd
  https://sigma.octopart.com/140413/datasheet/Lumex-LDM-24488NI.pdf
  a kivezetések csatlakoztatásához.

  Más LED-katódos oszlopmátrixok esetén csak a row[] és column[] tömbök kivezetés-számait kell megváltoztatnia.

  sorok az anódok
  oszlopok a katódok
  ---------

  Kivezetés-számok:
  Matrix:
  - digitális kivezetések 2 - 13,
  - analóg kivezetések 2 - 5 digitálisként használhatók, 16 - 19
  Potenciométerek:
  - a középső csatlakozó az analóg 0 és 1-re csatlakoztatva
  - a szélső csatlakozók a +5V-ra és a földre csatlakoztatva
  
  created 27 May 2009
  modified 30 Aug 2011
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/display/RowColumnScanning
*/

// A sorok kivezetés-számainak kétdimenziós tömbje:
const int row[8] = {
  2, 7, 19, 5, 13, 18, 12, 16
};

// Az oszlopok kivezetés-számainak kétdimenziós tömbje:
const int col[8] = {
  6, 11, 10, 3, 17, 4, 8, 9
};

// a pixelek kétdimenziós tömbje:
int pixels[8][8];

// kurzor pozíciója:
int x = 5;
int y = 5;

void setup() {
  // inicializálja az I/O kivetetéseket, ahogy a kimenetek a kivezetések között ismétlődnek:
  for (int thisPin = 0; thisPin < 8; thisPin++) {
    // inicializálja a kimeneti kivezetéseket:
    pinMode(col[thisPin], OUTPUT);
    pinMode(row[thisPin], OUTPUT);
    // emelje magasra a col kivezetéseket (azaz a katódokat), hogy biztosítsa a LED-ek kikapcsolását:
    digitalWrite(col[thisPin], HIGH);
  }

  // inicializálja a pixel mátrixot:
  for (int x = 0; x < 8; x++) {
    for (int y = 0; y < 8; y++) {
      pixels[x][y] = HIGH;
    }
  }
}

void loop() {
  // bemenet olvasása:
  readSensors();

  // rajzold meg a képernyőt:
  refreshScreen();
}

void readSensors() {
  // az utolsó pozíció kikapcsolása:
  pixels[x][y] = HIGH;
  // olvassa le az X és Y értékek érzékelőit:
  x = 7 - map(analogRead(A0), 0, 1023, 0, 7);
  y = map(analogRead(A1), 0, 1023, 0, 7);
  // állítsa az új pixelpozíciót alacsonyra, hogy a LED a következő
  // képernyőfrissítéskor bekapcsoljon:
  pixels[x][y] = LOW;

}

void refreshScreen() {
  // iteráld a sorokat (anódok):
  for (int thisRow = 0; thisRow < 8; thisRow++) {
    // vedd magasra a sor kivezetéseket (anódot):
    digitalWrite(row[thisRow], HIGH);
    // iteráld az oszlopokat (katódok):
    for (int thisCol = 0; thisCol < 8; thisCol++) {
      // lekérni az aktuális pixel állapotát;
      int thisPixel = pixels[thisRow][thisCol];
      // Ha a sor HIGH és a col LOW, a LED, ahol találkoznak,
      // felgyullad:
      digitalWrite(col[thisCol], thisPixel);
      // kapcsold ki a pixelt:
      if (thisPixel == LOW) {
        digitalWrite(col[thisCol], HIGH);
      }
    }
    // húzza le a sor kivezetéseket az egész sor kikapcsolásához:
    digitalWrite(row[thisRow], LOW);
  }
}