/*
  Memsic2125

  A Memsic 2125 kéttengelyes gyorsulásmérő olvasása. A 2125 által
  kibocsátott impulzusokat milli-g-re (a Föld gravitációjának 1/1000-e)
  alakítja át, és kinyomtatja őket a számítógép soros kapcsolatán keresztül.

  Az áramkör:
	- A gyorsulásmérő X kimenete a 2. digitális kivezetéshez
	- A gyorsulásmérő Y kimenete a 3. digitális kivezetéshez
	- A gyorsulásmérő +V kivezetése az +5V-hoz
	- A gyorsulásmérő GND kivezetésea fölghöz

  created 6 Nov 2008
  by David A. Mellis
  modified 30 Aug 2011
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/sensors/Memsic2125
*/

// ezek az állandók nem változnak:
const int xPin = 2;		// A gyorsulásmérő X kimenete
const int yPin = 3;		// A gyorsulásmérő Y kimenete

void setup() {
  // soros kommunikáció inicializálása:
  Serial.begin(9600);
  // inicializálja a gyorsulásmérőhöz csatlakoztatott kivezetéseket bemenetként:
  pinMode(xPin, INPUT);
  pinMode(yPin, INPUT);
}

void loop() {
  // változók az impulzusszélességek olvasásához:
  int pulseX, pulseY;
  // változók, amelyek tartalmazzák az eredményül kapott gyorsulásokat
  int accelerationX, accelerationY;

  // impulzus olvasása az x és y tengelyről:
  pulseX = pulseIn(xPin, HIGH);
  pulseY = pulseIn(yPin, HIGH);

  // konvertálja az impulzus szélességét gyorsulássá
  // accelerationX és accelerationY milli-g-ben:
  // A Föld gravitációja 1000 milli-g, vagy 1 g.
  accelerationX = ((pulseX / 10) - 500) * 8;
  accelerationY = ((pulseY / 10) - 500) * 8;

  // nyomtassa ki a gyorsulást
  Serial.print(accelerationX);
  // tabulátor karaktert nyomtat:
  Serial.print("\t");
  Serial.print(accelerationY);
  Serial.println();

  delay(100);
}