/*
  Comparing Strings

  Példák a karakterláncok összehasonlítására az összehasonlító operátorok használatával

  created 27 Jul 2010
  modified 2 Apr 2012
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/strings/StringComparisonOperators
*/

String stringOne, stringTwo;

void setup() {
  // Nyissa meg a soros kommunikációt, és várja meg, amíg megnyílik a port:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
  }


  stringOne = String("this");
  stringTwo = String("that");
  // küldj bevezetőt:
  Serial.println("\n\nComparing Strings:");
  Serial.println();

}

void loop() {
  // a két String egyenlő:
  if (stringOne == "this") {
    Serial.println("StringOne == \"this\"");
  }
  // a két String nem egyenlő:
  if (stringOne != stringTwo) {
    Serial.println(stringOne + " =! " + stringTwo);
  }

  // a két String nem egyenlő (a kis- és nagybetűk érzékenysége számít):
  stringOne = "This";
  stringTwo = "this";
  if (stringOne != stringTwo) {
    Serial.println(stringOne + " =! " + stringTwo);
  }
  // az equals()-t is használhatja annak ellenőrzésére, hogy két karakterlánc azonos-e:
  if (stringOne.equals(stringTwo)) {
    Serial.println(stringOne + " equals " + stringTwo);
  } else {
    Serial.println(stringOne + " does not equal " + stringTwo);
  }

  // vagy esetleg figyelmen kívül szeretné hagyni a kis- és nagybetűket:
  if (stringOne.equalsIgnoreCase(stringTwo)) {
    Serial.println(stringOne + " equals (ignoring case) " + stringTwo);
  } else {
    Serial.println(stringOne + " does not equal (ignoring case) " + stringTwo);
  }

  // egy numerikus karakterlánc az általa képviselt számhoz hasonlítva:
  stringOne = "1";
  int numberOne = 1;
  if (stringOne.toInt() == numberOne) {
    Serial.println(stringOne + " = " + numberOne);
  }



  // két numerikus String összehasonlítása:
  stringOne = "2";
  stringTwo = "1";
  if (stringOne >= stringTwo) {
    Serial.println(stringOne + " >= " + stringTwo);
  }

  // Az összehasonlító operátorok a karakterláncok alfabetikus rendezéshez is használhatók:
  stringOne = String("Brown");
  if (stringOne < "Charles") {
    Serial.println(stringOne + " < Charles");
  }

  if (stringOne > "Adams") {
    Serial.println(stringOne + " > Adams");
  }

  if (stringOne <= "Browne") {
    Serial.println(stringOne + " <= Browne");
  }


  if (stringOne >= "Brow") {
    Serial.println(stringOne + " >= Brow");
  }

  // az compareTo() operátor lehetővé teszi az általa kiértékelt karakterláncok
  // összehasonlítását is az első eltérő karakterig.
  // ha az összehasonlítandó karakterlánc első karaktere alfanumerikus sorrendben
  // előbb van, akkor az compareTo() nagyobb, mint 0:
  stringOne = "Cucumber";
  stringTwo = "Cucuracha";
  if (stringOne.compareTo(stringTwo) < 0) {
    Serial.println(stringOne + " comes before " + stringTwo);
  } else {
    Serial.println(stringOne + " comes after " + stringTwo);
  }

  delay(10000);  // mert a következő rész egy ciklus:

  // Az compareTo() akkor hasznos, ha számokat tartalmazó karakterláncok is vannak:

  while (true) {
    stringOne = "Sensor: ";
    stringTwo = "Sensor: ";

    stringOne += analogRead(A0);
    stringTwo += analogRead(A5);

    if (stringOne.compareTo(stringTwo) < 0) {
      Serial.println(stringOne + " comes before " + stringTwo);
    } else {
      Serial.println(stringOne + " comes after " + stringTwo);

    }
  }
}