String objektum konstruktorok

String objektumok inicializálása.

Utolsó felülvizsgálat: 2022.02.04 16:50

A String objektum lehetővé teszi a szöveges karakterláncok sokféle hasznos kezelését. Karaktereket fűzhet a karakterláncokhoz, összefűzéssel kombinálhatja a karakterláncokat, lekérheti a karakterlánc hosszát, kereshet és cserélhet részkarakterláncokat stb. Ez az oktatóanyag bemutatja, hogyan kell inicializálni a String objektumokat.

String stringOne = "Hello String";                      //  String állandó használata
String stringOne =  String('a');                        // karakter állandó átalakítása Stringgé
String stringTwo =  String("This is a string");         // string állandó átalakítása String objektummá
String stringOne =  String(stringTwo + " with more");   // két string összefűzése
String stringOne =  String(13);                         // egész állandó használata
String stringOne =  String(analogRead(0), DEC);         // egész és alap használata
String stringOne =  String(45, HEX);                    // egész és alap használata (hexadecimális)
String stringOne =  String(255, BIN);                   // egész és alap használata (bináris)
String stringOne =  String(millis(), DEC);              // long és alap használata
String stringOne =  String(5.698, 3);                   // lebegőpontos szám és tizedeshelyek használata

Mindezek a módszerek érvényesek egy String objektum deklarálására. Mindegyik egy olyan objektumot eredményez, amely karakterláncot tartalmaz, amely a String metódusok bármelyikével manipulálható. Ha látni szeretné őket működés közben, töltse fel az alábbi kódot egy Arduino kártyára, és nyissa meg az Arduino IDE soros monitort. Látni fogja az egyes deklarációk eredményeit. Hasonlítsa össze az egyes println() által kinyomtatottakat a fenti deklarációkkal.

Hardver szükséglet

Arduino kártya

Az áramkör

Ebben a példában nincs áramkör, bár a kártyát USB-n keresztül kell csatlakoztatni a számítógéphez, és az Arduino Software (IDE) soros monitor ablakának nyitva kell lennie.

A kód

/*
  String constructors

  Példák karakterláncok létrehozására más adattípusokból

  created 27 Jul 2010
  modified 30 Aug 2011
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/strings/StringConstructors
*/

void setup() {
  // Nyissa meg a soros kommunikációt, és várja meg, amíg megnyílik a port:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
  }

  // küldj bevezetőt:
  Serial.println("\n\nString Constructors:");
  Serial.println();
}

void loop() {
  // string állandó használata:
  String stringOne = "Hello String";
  Serial.println(stringOne);      // nyomtatva: "Hello String"

  // karakter állandó átalakítása Stringgé:
  stringOne =  String('a');
  Serial.println(stringOne);       // nyomtatva: "a"

  // string állandó átalakítása String objektummá:
  String stringTwo =  String("This is a string");
  Serial.println(stringTwo);      // nyomtatva: "This is a string"

  // két string összefűzése:
  stringOne =  String(stringTwo + " with more");
  // nyomtatva: "This is a string with more":
  Serial.println(stringOne);

  // egész állandó használata:
  stringOne =  String(13);
  Serial.println(stringOne);      // nyomtatva: "13"

  // egész és alap használata:
  stringOne =  String(analogRead(A0), DEC);
  // nyomtatva: "453" or whatever the value of analogRead(A0) is
  Serial.println(stringOne);

  // egész és alap használata (hexadecimális):
  stringOne =  String(45, HEX);
  // nyomtatva: "2d", which is the hexadecimal version of decimal 45:
  Serial.println(stringOne);

  // egész és alap használata (bináris)
  stringOne =  String(255, BIN);
  // nyomtatva: "11111111" which is the binary value of 255
  Serial.println(stringOne);

  // long és alap használatae:
  stringOne =  String(millis(), DEC);
  // nyomtatva: "123456" or whatever the value of millis() is:
  Serial.println(stringOne);

  // lebegőpontos szám és helyes tizedeshelyek használata:
  stringOne = String(5.698, 3);
  Serial.println(stringOne);

  // lebegőpontos szám és kevesebb tizedeshelyek használata kerekítéssel:
  stringOne = String(5.698, 2);
  Serial.println(stringOne);

  // ne csinálj semmit, amíg igaz:
  while (true);

}

Tudj meg többet

További alapvető oktatóanyagokat a beépített példák részben talál.

Felfedezheti a nyelvi referenciát is, az Arduino programozási nyelv részletes gyűjteményét.