String replace függvény

A replace() függvény lehetővé teszi, hogy egy karakterláncban egy adott karakter összes példányát lecseréljük egy másik karakterre.

Utolsó felülvizsgálat: 2022.02.04 16:50

A String replace() függvénye lehetővé teszi, hogy egy adott karakter minden példányát lecseréljük egy másik karakterre. A replace funkcióval egy karakterlánc részkarakterláncait is lecserélheti egy másik részkarakterláncra.

Hardver szükséglet

  • Arduino kártya

Az áramkör

Ebben a példában nincs áramkör, bár a kártyát USB-n keresztül kell csatlakoztatni a számítógéphez, és az Arduino Software (IDE) soros monitor ablakának nyitva kell lennie.

A kód

Vigyázat: Ha olyan részkarakterláncot próbál meg lecserélni, amely több, mint maga a karakterlánc, semmi sem cserélődik le. Például:

String stringOne = "<html><head><body>";
String stringTwo = stringOne.replace("<html><head></head><body></body></html>", "Blah");

Ebben az esetben a kód lefordításra kerül, de a stringOne változatlan marad, mivel a helyettesítő részkarakterlánc több, mint maga a String.

/*
  String replace()

  Példák egy karakterlánc karaktereinek vagy részkarakterláncainak cseréjére

  created 27 Jul 2010
  modified 2 Apr 2012
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/strings/StringReplace
*/

void setup() {
  // Nyissa meg a soros kommunikációt, és várja meg, amíg megnyílik a port:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
  }

  // küldj bevezetőt:
  Serial.println("\n\nString replace:\n");
  Serial.println();
}

void loop() {
  String stringOne = "<html><head><body>";
  Serial.println(stringOne);
  // A replace() megváltoztatja az egyik részkarakterlánc összes példányát
  // egy másikkal: először készítsen másolatot az eredeti karakterláncról:
  String stringTwo = stringOne;
  // majd végezze el a cseréket:
  stringTwo.replace("<", "</");
  // az eredeti nyomtatása:
  Serial.println("Original string: " + stringOne);
  // és a módosított string nyomtatása:
  Serial.println("Modified string: " + stringTwo);

  // a replace()-t használhatja egyedi karaktereknél is:
  String normalString = "bookkeeper";
  Serial.println("normal: " + normalString);
  String leetString = normalString;
  leetString.replace('o', '0');
  leetString.replace('e', '3');
  Serial.println("l33tspeak: " + leetString);

  // ne csinálj semmit, amíg igaz:
  while (true);
}

Tudj meg többet

További alapvető oktatóanyagokat a beépített példák részben talál.

Felfedezheti a nyelvi referenciát is, az Arduino programozási nyelv részletes gyűjteményét.