/*
  ButtonMouseControl

  Csak Leonardo és Due kártyákhoz.

  Az Arduino Leonardo, Micro vagy Due öt nyomógombbal vezérli az egeret.

  Hardware:
  - öt nyomógomb a D2, D3, D4, D5, D6-hoz csatlakoztatva

  Az egér mozgása mindig relatív. Ez a vázlat négy nyomógombot olvas,
  és ezek segítségével állítja be az egér mozgását. 

  FIGYELEM: Amikor a Mouse.move() parancsot használja, az Arduino átveszi az egeret!
  Az egérparancsok használata előtt győződjön meg arról, hogy rendelkezik a vezérléssel. 

  created 15 Mar 2012
  modified 27 Mar 2012
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/usb/ButtonMouseControl
*/

#include "Mouse.h"

// állítsa be a kivezetésszámokat az öt gombhoz:
const int upButton = 2;
const int downButton = 3;
const int leftButton = 4;
const int rightButton = 5;
const int mouseButton = 6;

int range = 5;              // X vagy Y mozgás kimeneti tartománya; befolyásolja a mozgás sebességét 
int responseDelay = 10;     // az egér válaszkésleltetése, ms-ban


void setup() {
  // inicializálja a gombok bemeneteit:
  pinMode(upButton, INPUT);
  pinMode(downButton, INPUT);
  pinMode(leftButton, INPUT);
  pinMode(rightButton, INPUT);
  pinMode(mouseButton, INPUT);
  // inicializálja az egérvezérlést:
  Mouse.begin();
}

void loop() {
  // olvasd le a gombokat:
  int upState = digitalRead(upButton);
  int downState = digitalRead(downButton);
  int rightState = digitalRead(rightButton);
  int leftState = digitalRead(leftButton);
  int clickState = digitalRead(mouseButton);

  // Számítsa ki a mozgási távolságot a gomb állapotai alapján:
  int  xDistance = (leftState - rightState) * range;
  int  yDistance = (upState - downState) * range;

  // ha X vagy Y nem nulla, mozgassa:
  if ((xDistance != 0) || (yDistance != 0)) {
    Mouse.move(xDistance, yDistance, 0);
  }

  // ha megnyomja az egérgombot:
  if (clickState == HIGH) {
    // ha az egér nincs lenyomva, nyomja meg:
    if (!Mouse.isPressed(MOUSE_LEFT)) {
      Mouse.press(MOUSE_LEFT);
    }
  }
  // else nincs megnyomva az egérgomb:
  else {
    // ha meg van nyomva az egér, engedje el:
    if (Mouse.isPressed(MOUSE_LEFT)) {
      Mouse.release(MOUSE_LEFT);
    }
  }

  // késleltetés, hogy az egér ne mozogjon túl gyorsan:
  delay(responseDelay);
}