/*
  JoystickMouseControl

  Az egeret az Arduino Leonardo, Micro vagy Due joystickjával vezérli.
  Egy nyomógombot használ az egérvezérlés be- és kikapcsolására, egy második 
  nyomógombot pedig a bal egérgombbal való kattintáshoz.

  Hardware:
  - 2 tengelyes joystick az A0 és A1 kivezetésekhez csatlakoztatva
  - nyomógombok, amelyek a D2 és D3 kivezetésekhez csatlakoznak

  Az egér mozgása mindig relatív. Ez a vázlat két analóg bemenetet olvas be,
  amelyek 0-tól 1023-ig terjednek (vagy mindkét végén kevesebb), és lefordítja
  őket -6 és 6 közötti tartományba.
  A vázlat feltételezi, hogy a joystick nyugalmi értékei a tartomány közepe
  körül vannak, de egy küszöbön belül változnak.

  FIGYELEM: Amikor a Mouse.move() parancsot használja, az Arduino átveszi az egeret!
  Az egérparancsok használata előtt győződjön meg arról, hogy rendelkezik a vezérléssel. Ez a vázlat
  tartalmaz egy nyomógombot az egérvezérlés állapotának váltásához, így be- és kikapcsolhatja
  az egérvezérlést.

  created 15 Sep 2011
  updated 28 Mar 2012
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/usb/JoystickMouseControl
*/

#include "Mouse.h"

// Kivezetés-számok beállítása a kapcsolókhoz, a joystick tengelyekhez és a LED-hez:
const int switchPin = 2;      // kapcsoló az egérvezérlés be- és kikapcsolásához
const int mouseButton = 3;    // bemeneti kivezetés az egér nyomógombjához
const int xAxis = A0;         // joystick X tengely
const int yAxis = A1;         // joystick Y tengely
const int ledPin = 5;         // Egér vezérlő LED

// parameters for reading the joystick:
int range = 12;               // X vagy Y mozgás kimeneti tartománya
int responseDelay = 5;        // az egér válaszkésleltetése, ms-ban
int threshold = range / 4;    // nyugalmi küszöb
int center = range / 2;       // nyugalmi helyzet értéke

bool mouseIsActive = false;    // irányítani kell-e az egeret vagy sem
int lastSwitchState = LOW;        // előző kapcsoló állapot

void setup() {
  pinMode(switchPin, INPUT);       // a kapcsoló kivezetés
  pinMode(ledPin, OUTPUT);         // a LED kivezetés
  // vegye át az irányítást az egér felett:
  Mouse.begin();
}

void loop() {
  // a kapcsoló olvasása:
  int switchState = digitalRead(switchPin);
  // ha megváltozott és magas, váltsd át az egér állapotát:
  if (switchState != lastSwitchState) {
    if (switchState == HIGH) {
      mouseIsActive = !mouseIsActive;
      // kapcsolja be a LED-et, hogy jelezze az egér állapotát:
      digitalWrite(ledPin, mouseIsActive);
    }
  }
  // kapcsoló állapotának mentése a következő összehasonlításhoz:
  lastSwitchState = switchState;

  // olvassa el és skálázza a két tengelyt:
  int xReading = readAxis(A0);
  int yReading = readAxis(A1);

  // ha az egérvezérlő állapot aktív, mozgassa az egeret:
  if (mouseIsActive) {
    Mouse.move(xReading, yReading, 0);
  }

  // olvassa el az egérgombot, és kattintson vagy ne kattintson:
  // ha megnyomja az egérgombot:
  if (digitalRead(mouseButton) == HIGH) {
    // ha az egér nincs lenyomva, nyomja meg:
    if (!Mouse.isPressed(MOUSE_LEFT)) {
      Mouse.press(MOUSE_LEFT);
    }
  }
  // else nincs megnyomva az egérgomb:
  else {
    // ha megnyomja az egeret, engedje el:
    if (Mouse.isPressed(MOUSE_LEFT)) {
      Mouse.release(MOUSE_LEFT);
    }
  }

  delay(responseDelay);
}

/*
  beolvas egy tengelyt (0 vagy 1 x-hez vagy y-hoz), és az analóg bemeneti tartományt
  0 és <tartomány> közötti tartományra skálázza
*/

int readAxis(int thisAxis) {
  // az analóg bemenet olvasása:
  int reading = analogRead(thisAxis);

  // az analóg bemeneti tartományból a kimeneti tartományra való leképezés:
  reading = map(reading, 0, 1023, 0, range);

  // ha a kimeneti érték kívül esik a nyugalmi helyzet küszöbén, használja:
  int distance = reading - center;

  if (abs(distance) < threshold) {
    distance = 0;
  }

  // visszaadja a tengely távolságát:
  return distance;
}