/*
  KeyboardAndMouseControl

  Az Arduino Leonardo, Micro vagy Due öt nyomógombbal vezérli az egeret.

  Hardware:
  - öt nyomógomb D2, D3, D4, D5, D6-hoz csatlakoztatva

  Az egér mozgása mindig relatív. Ez a vázlat négy nyomógombot olvas,
  és ezek segítségével állítja be az egér mozgását.

  FIGYELEM: Amikor a Mouse.move() parancsot használja, az Arduino átveszi az egeret!
  Az egérparancsok használata előtt győződjön meg arról, hogy rendelkezik a vezérléssel.

  created 15 Mar 2012
  modified 27 Mar 2012
  by Tom Igoe

  Ez a kód nyilvános.

  https://docs.arduino.cc/built-in-examples/usb/KeyboardAndMouseControl
*/

#include "Keyboard.h"
#include "Mouse.h"

// állítsa be a kivezetés-számokat az öt gombhoz:
const int upButton = 2;
const int downButton = 3;
const int leftButton = 4;
const int rightButton = 5;
const int mouseButton = 6;

void setup() { // inicializálja a gombok bemeneteit:
  pinMode(upButton, INPUT);
  pinMode(downButton, INPUT);
  pinMode(leftButton, INPUT);
  pinMode(rightButton, INPUT);
  pinMode(mouseButton, INPUT);

  Serial.begin(9600);
  // inicializálja az egérvezérlést:
  Mouse.begin();
  Keyboard.begin();
}

void loop() {
  // használjon soros bemenetet az egér vezérléséhez:
  if (Serial.available() > 0) {
    char inChar = Serial.read();

    switch (inChar) {
      case 'u':
        // mozgassa felfelé az egeret
        Mouse.move(0, -40);
        break;
      case 'd':
        // mozgassa lefelé az egeret
        Mouse.move(0, 40);
        break;
      case 'l':
        // mozgassa balra az egeret
        Mouse.move(-40, 0);
        break;
      case 'r':
        // mozgassa jobbra az egeret
        Mouse.move(40, 0);
        break;
      case 'm':
        // végezze el az egér bal gombkattintását
        Mouse.click(MOUSE_LEFT);
        break;
    }
  }

  // használja a nyomógombokat a billentyűzet vezérléséhez:
  if (digitalRead(upButton) == HIGH) {
    Keyboard.write('u');
  }
  if (digitalRead(downButton) == HIGH) {
    Keyboard.write('d');
  }
  if (digitalRead(leftButton) == HIGH) {
    Keyboard.write('l');
  }
  if (digitalRead(rightButton) == HIGH) {
    Keyboard.write('r');
  }
  if (digitalRead(mouseButton) == HIGH) {
    Keyboard.write('m');
  }

}