WiFi.config() - Arduino referencia

WiFi.config()

Leírás

A WiFi.config() lehetővé teszi egy statikus IP-cím konfigurálását, valamint a DNS, az átjáró és az alhálózati címek megváltoztatását a WiFi pajzson.

A WiFi.begin() függvénytől eltérően, amely automatikusan beállítja a WiFi pajzsot a DHCP használatára, a WiFi.config() lehetővé teszi a pajzs hálózati címének manuális beállítását.

A WiFi.config() meghívása a WiFi.begin() előtt arra kényszeríti a begin()-t, hogy a WiFi pajzsot a config()-ban megadott hálózati címekkel konfigurálja.

A WiFi.config() meghívható a WiFi.begin() után, de a pajzs az alapértelmezett DHCP módban a begin() paranccsal inicializálódik. A config() metódus meghívása után a kérésnek megfelelően megváltoztatja a hálózati címet.

Szintaxis

WiFi.config(ip)
WiFi.config(ip, dns)
WiFi.config(ip, dns, gateway)
WiFi.config(ip, dns, gateway, subnet)

Paraméterek

ip: az eszköz IP-címe (4 bájtos tömb).
dns: a DNS-kiszolgáló címe.
gateway: a hálózati átjáró IP-címe (4 bájtos tömb). Opcionális: alapértelmezés szerint az eszköz IP-címe, az utolsó oktett 1-re van állítva.
subnet: a hálózat alhálózati maszkja (4 bájtos tömb). Opcionális: alapértelmezés szerint 255.255.255.0.

Visszatérési érték

Nincs

Példa

Ez a példa bemutatja, hogyan kell beállítani a LAN hálózat statikus IP-címét (192.168.0.177) a WiFi pajzsra:

#include <SPI.h>
#include <WiFi.h>

// a pajzs IP-címe:
IPAddress ip(192, 168, 0, 177);    

char ssid[] = "yourNetwork";    // a hálózati SSID (név)
char pass[] = "secretPassword"; // a hálózati jelszava (használja a WPA-hoz, vagy használja kulcsként a WEP-hez)

int status = WL_IDLE_STATUS;

void setup()
{  
  // Inicializálja a soros portot, és várja meg, amíg megnyílik:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak Leonardo-hoz kell
  }

  // ellenőrizze a pajzs meglétét:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    while(true);  // ne folytassa
  }

  WiFi.config(ip);

  // próbáljon meg csatlakozni a Wifi hálózathoz:
  while ( status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Csatlakozás WPA/WPA2 hálózathoz. Nyílt vagy WEP hálózat használata esetén módosítsa ezt a sort:    
    status = WiFi.begin(ssid, pass);

    // várjon 10 másodpercet a csatlakozásra:
    delay(10000);
  }

  // nyomtassa ki a WiFi pajzs IP-címét:
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());
}

void loop () {}