WiFi - Wifi.status() - Arduino referencia

WiFi - WiFi.status()

Leírás

Visszaadja a kapcsolat állapotát..

Szintaxis

WiFi.status()

Paraméterek

Nincs

Visszatérési érték

WL_CONNECTED: akkor van hozzárendelve, ha csatlakozik WiFi hálózathoz.
WL_NO_SHIELD: akkor van hozzárendelve, ha nincs WiFi pajzs.
WL_IDLE_STATUS: ez egy ideiglenes állapot, amelyet a WiFi.begin() meghívásakor rendelnek hozzá, és aktív marad mindaddig, amíg a kísérletek száma le nem jár (ami a WL_CONNECT_FAILED-t eredményezi), vagy a kapcsolat létre nem jön (WL_CONNECTED az eredménye).
WL_NO_SSID_AVAIL: akkor van hozzárendelve, ha nem áll rendelkezésre az SSID.
WL_SCAN_COMPLETED: akkor van hozzárendelve, ha hálózatok keresése teljes.
WL_CONNECT_FAILED: akkor van hozzárendelve, ha a kapcsolat minden próbálkozásnál meghiúsul.
WL_CONNECTION_LOST: akkor van hozzárendelve, ha a kapcsolat megszakadt.
WL_DISCONNECTED: akkor van hozzárendelve, amikor leválasztják a hálózatról.

Példa

#include <SPI.h>
#include <WiFi.h>

char ssid[] = "yourNetwork";                     // a hálózati SSID (név)
char key[] = "D0D0DEADF00DABBADEAFBEADED";       // a hálózati kulcs
int keyIndex = 0;                                // a hálózati kulcs indexszáma
int status = WL_IDLE_STATUS;                     // a Wifi rádió állapota

void setup() {
  //Inicializálja a soros portot, és várja meg, amíg megnyílik:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak Leonardo-hoz kell
  }

  // ellenőrzi a pajzs meglétét:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // don't continue:
    while (true);
  }

  // próbáljon meg csatlakozni a Wifi hálózathoz:
  while ( status != WL_CONNECTED) {
    Serial.print("Attempting to connect to WEP network, SSID: ");
    Serial.println(ssid);
    status = WiFi.begin(ssid, keyIndex, key);

    // várjon 10 másodpercet a csatlakozásra:
    delay(10000);
  }

  // miután csatlakozott:
  Serial.print("You're connected to the network");
}

void loop() {
  // ellenőrizze a hálózati kapcsolat állapotát 10 másodpercenként:
  delay(10000);
 Serial.println(WiFi.status());
}