/*
 Udp NTP kliens

 Kérje le az időt a Network Time Protocol (NTP) időkiszolgálótól.
 Az UDP sendPacket és ReceivePacket használatát mutatja be.
 Az NTP időszerverekről és a velük való kommunikációhoz szükséges üzenetekről
 olvasd a https://en.wikipedia.org/wiki/Network_Time_Protocol oldalt.

 created 4 Sep 2010
 by Michael Margolis
 modified 9 Apr 2012
 by Tom Igoe

 Ez a kód nyilvános
 */

#include <SPI.h>
#include <WiFi.h>
#include <WiFiUdp.h>

int status = WL_IDLE_STATUS;
char ssid[] = "mynetwork";        // a hálózatának SSID-je (neve)
char pass[] = "mypassword";       // a hálózati jelszava
int keyIndex = 0;            // a hálózati kulcs indexszáma (csak a WEP-hez szükséges)

unsigned int localPort = 2390;      // a figyelt helyi port

IPAddress timeServer(129, 6, 15, 28); // time.nist.gov NTP szerver

const int NTP_PACKET_SIZE = 48; // Az NTP időbélyeg az üzenet első 48 bájtjában található

byte packetBuffer[ NTP_PACKET_SIZE]; // puffer a bejövő és kimenő csomagok tárolására

// UDP-példány, amellyel csomagokat küldhetünk és fogadhatunk UDP-n keresztül
WiFiUDP Udp;

void setup() {
  // Inicializálja a soros portot, és várja meg, amíg megnyílik:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
  }

  // ellenőrizze a pajzs meglétét:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // Ne folytasd:
    while (true);
  }

  String fv = WiFi.firmwareVersion();
  if (fv != "1.1.0") {
    Serial.println("Please upgrade the firmware");
  }

  // próbáljon meg csatlakozni a Wifi hálózathoz:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Csatlakozás WPA/WPA2 hálózathoz. Nyílt vagy WEP hálózat
    // használata esetén módosítsa ezt a sort:
    status = WiFi.begin(ssid, pass);

    // várjon 10 másodpercet a csatlakozásra:
    delay(10000);
  }

  Serial.println("Connected to wifi");
  printWifiStatus();

  Serial.println("\nStarting connection to server...");
  Udp.begin(localPort);
}

void loop() {
  sendNTPpacket(timeServer); // küldjön egy NTP-csomagot egy időszervernek
  // várjon, hátha van válasz
  delay(1000);
  if (Udp.parsePacket()) {
    Serial.println("packet received");
    // Kaptunk egy csomagot, kiolvastuk belőle az adatokat
    Udp.read(packetBuffer, NTP_PACKET_SIZE); // olvassa be a csomagot a pufferbe

    // az időbélyeg a fogadott csomag 40. bájtjánál kezdődik, és négy bájt
    // vagy két szó hosszúságú. Először vonja ki a két szót:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);
    // kombinálja a négy bájtot (két szót) egy hosszú egész számmá
    // ez az NTP idő (másodpercek 1900. január 1. óta):
    unsigned long secsSince1900 = highWord << 16 | lowWord;
    Serial.print("Seconds since Jan 1 1900 = ");
    Serial.println(secsSince1900);

    // most konvertálja át az NTP-időt mindennapi idővé:
    Serial.print("Unix time = ");
    // A Unix időszámítása 1970. január 1-jén kezdődik. Másodpercekben ez 2208988800:
    const unsigned long seventyYears = 2208988800UL;
    // skivonjuk a hetven évet:
    unsigned long epoch = secsSince1900 - seventyYears;
    // kinyomtatjuk az Unix időt:
    Serial.println(epoch);


    // nyomtassa ki az órát, percet és másodpercet:
    Serial.print("The UTC time is ");       // UTC a greenwichi meridián (GMT) ideje
    Serial.print((epoch  % 86400L) / 3600); // nyomtatja ki az órát (86400 másodpercnek felel meg naponta)
    Serial.print(':');
    if (((epoch % 3600) / 60) < 10) {
      // Iminden óra első 10 percében 0-val akarunk kezdeni
      Serial.print('0');
    }
    Serial.print((epoch  % 3600) / 60); // percek nyomtatása (3600 másodpercenként)
    Serial.print(':');
    if ((epoch % 60) < 10) {
      // Minden perc első 10 másodpercében 0-t akarunk
      Serial.print('0');
    }
    Serial.println(epoch % 60); // nyomtasd ki a másodperceket
  }
  // várjon tíz másodpercet, mielőtt újra megkérdezné az időt
  delay(10000);
}

// küldjön egy NTP kérést az időszervernek a megadott címen
unsigned long sendNTPpacket(IPAddress& address) {
  //Serial.println("1");
  // állítsa a puffer összes bájtját 0-ra
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Inicializálja az NTP-kérés létrehozásához szükséges értékeket
  // (lásd a fenti URL-t a csomagokkal kapcsolatos részletekért)
  //Serial.println("2");
  packetBuffer[0] = 0b11100011;   // LI, verzió, mód
  packetBuffer[1] = 0;     // Réteg, vagy óratípus
  packetBuffer[2] = 6;     // Lekérdezési intervallum
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  //Serial.println("3");

  // minden NTP mező értéket kapott, most már 
  // küldhet egy csomagot, amely időbélyeget kér:
  Udp.beginPacket(address, 123); //NTP requests are to port 123
  //Serial.println("4");
  Udp.write(packetBuffer, NTP_PACKET_SIZE);
  //Serial.println("5");
  Udp.endPacket();
  //Serial.println("6");
}


void printWifiStatus() {
  // nyomtassa ki annak a hálózatnak az SSID-jét, amelyhez csatlakozik:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // nyomtassa ki a WiFi pajzs IP-címét:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // nyomtassa ki a vett jelerősséget:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}