/*
 Chat szerver

 Egy egyszerű szerver, amely minden bejövő üzenetet eloszt az összes
 csatlakoztatott kliens között. Használja a Telnet-et az eszköz IP-címéhez
 és típusához. A kliens bemenetét a soros monitoron is láthatja.

 Ez a példa WPA titkosítást használó hálózathoz íródott. WEP vagy
 WPA esetén ennek megfelelően módosítsa a Wifi.begin() hívást.

 Az áramkör:
 * Csatolt WiFi pajzs

 created 18 Dec 2009
 by David A. Mellis
 modified 31 May 2012
 by Tom Igoe
 */

#include <SPI.h>
#include <WiFi.h>

char ssid[] = "yourNetwork";       // a hálózatának SSID-je (neve)
char pass[] = "secretPassword";    // a hálózati jelszava (használja a WPA-hoz, vagy használja kulcsként a WEP-hez)

int keyIndex = 0;            // a hálózati kulcs indexszáma (csak a WEP-hez szükséges)

int status = WL_IDLE_STATUS;

WiFiServer server(23);

boolean alreadyConnected = false; // hogy az ügyfél korábban csatlakozott-e vagy sem

void setup() {
  // Inicializálja a soros portot, és várja meg, amíg megnyílik:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
  }

  // ellenőrizze a pajzs meglétét:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // Ne folytasd:
    while (true);
  }

  String fv = WiFi.firmwareVersion();
  if (fv != "1.1.0") {
    Serial.println("Please upgrade the firmware");
  }

  // próbáljon meg csatlakozni a Wifi hálózathoz:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Csatlakozás WPA/WPA2 hálózathoz. Nyílt vagy WEP hálózat
    // használata esetén módosítsa ezt a sort:
    status = WiFi.begin(ssid, pass);

    // várjon 10 másodpercet a csatlakozásra:
    delay(10000);
  }

  // start the server:
  server.begin();
  // most csatlakozik, ezért nyomtassa ki az állapotot:
  printWifiStatus();
}


void loop() {
  // várakozás új kliensre:
  WiFiClient client = server.available();


  // Amikor a kliens elküldi az első bájtot, köszönjön:
  if (client) {
    if (!alreadyConnected) {
      // törölje a bemeneti puffert:
      client.flush();
      Serial.println("We have a new client");
      client.println("Hello, client!");
      alreadyConnected = true;
    }

    if (client.available() > 0) {
      // olvassa be a klienstől érkező bájtokat:
      char thisChar = client.read();
      // echozza vissza a bájtokat az ügyfélnek:
      server.write(thisChar);
      // echozza a bájtokat a szervernek is:
      Serial.write(thisChar);
    }
  }
}


void printWifiStatus() {
  // nyomtassa ki annak a hálózatnak az SSID-jét, amelyhez csatlakozik:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // nyomtassa ki a WiFi pajzs IP-címét:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // nyomtassa ki a vett jelerősséget:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}