/*
  WiFi UDP String küldése és fogadása

 Ez a vázlat egy UDP-csomagra vár a localPort-on WiFi pajzs használatával.
 Amikor egy csomag érkezik, egy nyugtázási csomag kerül elküldésre a remotePort-on lévő ügyfélnek

 Az áramkör:
 * Csatolt WiFi pajzs

 created 30 December 2012
 by dlf (Metodo2 srl)
 */

#include <SPI.h>
#include <WiFi.h>
#include <WiFiUdp.h>

int status = WL_IDLE_STATUS;
char ssid[] = "yourNetwork";       // a hálózatának SSID-je (neve)
char pass[] = "secretPassword";    // a hálózati jelszava (használja a WPA-hoz, vagy használja kulcsként a WEP-hez)
int keyIndex = 0;                  // a hálózati kulcs indexszáma (csak a WEP-hez szükséges)

unsigned int localPort = 2390;     // a figyelt helyi port

char packetBuffer[255];            // puffer a bejövő csomagok tárolására
char ReplyBuffer[] = "acknowledged";       // visszaküldendő karakterlánc

WiFiUDP Udp;

void setup() {
  // Inicializálja a soros portot, és várja meg, amíg megnyílik:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
  }

  // ellenőrizze a pajzs meglétét:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // Ne folytasd:
    while (true);
  }

  String fv = WiFi.firmwareVersion();

  if (fv != "1.1.0") {
    Serial.println("Please upgrade the firmware");
  }

  // próbáljon meg csatlakozni a Wifi hálózathoz:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);

    // Csatlakozás WPA/WPA2 hálózathoz. Nyílt vagy WEP hálózat
    // használata esetén módosítsa ezt a sort:
    status = WiFi.begin(ssid);
    // várjon 10 másodpercet a csatlakozásra:
    delay(10000);
  }

  Serial.println("Connected to wifi");
  printWifiStatus();
  Serial.println("\nStarting connection to server...");
  // ha létrejön a kapcsolat, jelentsd vissza a soros porton keresztül:
  Udp.begin(localPort);
}

void loop() {
  // ha vannak elérhető adatok, olvass el egy csomagot
  int packetSize = Udp.parsePacket();
  if (packetSize) {
    Serial.print("Received packet of size ");
    Serial.println(packetSize);
    Serial.print("From ");
    IPAddress remoteIp = Udp.remoteIP();
    Serial.print(remoteIp);
    Serial.print(", port ");
    Serial.println(Udp.remotePort());
    // beolvassa a csomagot a packetBuffer-be
    int len = Udp.read(packetBuffer, 255);
    if (len > 0) {
      packetBuffer[len] = 0;
    }
    Serial.println("Contents:");
    Serial.println(packetBuffer);
    // küldjön választ arra az IP-címre és portra, amelyről a kapott csomagot küldtük
    Udp.beginPacket(Udp.remoteIP(), Udp.remotePort());
    Udp.write(ReplyBuffer);
    Udp.endPacket();
  }
}

void printWifiStatus() {
  // nyomtassa ki annak a hálózatnak az SSID-jét, amelyhez csatlakozik:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // nyomtassa ki a WiFi pajzs IP-címét:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // nyomtassa ki a vett jelerősséget:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}