/*
  Web kliens

 Ez a vázlat WiFi pajzs segítségével csatlakozik egy webhelyhez
 (http://www.google.com).
 Ez a példa WPA titkosítást használó hálózathoz íródott. WEP vagy
 nyilt hálózat esetén ennek megfelelően módosítsa a Wifi.begin() hívást.

Az áramkör:
 * Csatolt WiFi pajzs

 created 13 July 2010
 by dlf (Metodo2 srl)
 modified 31 May 2012
 by Tom Igoe
 */

#include <SPI.h>
#include <WiFi.h>

char ssid[] = "yourNetwork";       // a hálózatának SSID-je (neve)
char pass[] = "secretPassword";    // a hálózati jelszava (használja a WPA-hoz, vagy használja kulcsként a WEP-hez)

int keyIndex = 0;                  // a hálózati kulcs indexszáma (csak a WEP-hez szükséges)

int status = WL_IDLE_STATUS;
// ha nem akar DNS-t használni (és csökkenteni a vázlat méretét),
// használja a numerikus IP-t a szerver neve helyett:
//IPAddress server(74,125,232,128);  // numerikus IP a Google számára (nincs DNS)
char server[] = "www.google.com";    // név cím a Google számára (DNS használatával)

// Inicializálja az WiFi kliens könyvtárat annak a kiszolgálónak
// az IP-címével és portjával, amelyhez csatlakozni kíván (a 80-as
// port az alapértelmezett a HTTP-hez):

WiFiClient client;

void setup() {
  // Inicializálja a soros portot, és várja meg, amíg megnyílik:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
  }

  // ellenőrizze a pajzs meglétét:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // Ne folytasd:
    while (true);
  }
  String fv = WiFi.firmwareVersion();
  if (fv != "1.1.0") {
    Serial.println("Please upgrade the firmware");
  }
  // próbáljon meg csatlakozni a Wifi hálózathoz:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Csatlakozás WPA/WPA2 hálózathoz. Nyílt vagy WEP hálózat
    // használata esetén módosítsa ezt a sort:
    status = WiFi.begin(ssid, pass);
    // várjon 10 másodpercet a csatlakozásra:
    delay(10000);
  }
  Serial.println("Connected to wifi");
  printWifiStatus();
  Serial.println("\nStarting connection to server...");
  // ha létrejön a kapcsolat, jelentsd vissza a soros porton keresztül:
  if (client.connect(server, 80)) {
    Serial.println("connected to server");
    // HTTP kérés készítése:
    client.println("GET /search?q=arduino HTTP/1.1");
    client.println("Host: www.google.com");
    client.println("Connection: close");
    client.println();
  }
}

void loop() {
  // ha vannak bejövő bájtok a szerverről,
  // olvassa be és nyomtassa ki:
  while (client.available()) {
    char c = client.read();
    Serial.write(c);
  }
  // ha a szerver csatlakozása megszakad, állítsa le a klienst:
  if (!client.connected()) {
    Serial.println();
    Serial.println("disconnecting from server.");
    client.stop();
    // ne csinálj semmit többé:
    while (true);
  }
}

void printWifiStatus() {
  // nyomtassa ki annak a hálózatnak az SSID-jét, amelyhez csatlakozik:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());
  
  // nyomtassa ki a WiFi pajzs IP-címét:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);
  
  // nyomtassa ki a vett jelerősséget:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}