/*
  Ismétlődő Wi-Fi webkliens

 Ez a vázlat csatlakozik egy webszerverhez, és egy
 Arduino Wifi pajzs használatával kérést küld.

 Az áramkör:
 * WiFi-pajzs az SPI-kivezetésekhez és a 7-es kivezetéshez csatlakoztatva

 created 23 April 2012
 modified 31 May 2012
 by Tom Igoe
 modified 13 Jan 2014
 by Federico Vanzati
 https://docs.arduino.cc/library-examples/wifi-library/WiFiWebClientRepeating
 Ez a kód nyilvános.
 */

#include <SPI.h>
#include <WiFi.h>

char ssid[] = "yourNetwork";      // a hálózatának SSID-je (neve)
char pass[] = "secretPassword";   // a hálózati jelszava

int keyIndex = 0;            // a hálózati kulcs indexszáma (csak a WEP-hez szükséges)

int status = WL_IDLE_STATUS;

// Inicializálja az WiFi kliens könyvtárat
WiFiClient client;

// a szerver címe:
char server[] = "www.arduino.cc";
//IPAddress server(64,131,82,241);

unsigned long lastConnectionTime = 0;              // amikor legutóbb csatlakozott a szerverhez, ezredmásodpercben
const unsigned long postingInterval = 10L * 1000L; // késleltetés a frissítések között, ezredmásodpercben

void setup() {
  // Inicializálja a soros portot, és várja meg, amíg megnyílik:
  Serial.begin(9600);
  while (!Serial) {
    ; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
  }

  // ellenőrizze a pajzs meglétét:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // Ne folytasd:
    while (true);
  }

  String fv = WiFi.firmwareVersion();
  if (fv != "1.1.0") {
    Serial.println("Please upgrade the firmware");
  }

  // próbáljon meg csatlakozni a Wifi hálózathoz:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Csatlakozás WPA/WPA2 hálózathoz. Nyílt vagy WEP hálózat
    // használata esetén módosítsa ezt a sort:
    status = WiFi.begin(ssid, pass);
    // várjon 10 másodpercet a csatlakozásra:
    delay(10000);
  }

  // most csatlakozik, ezért nyomtassa ki az állapotot:
  printWifiStatus();
}

void loop() {
  // ha van bejövő adat a netkapcsolatról küldd ki
  // a soros porton. Ez csak hibakeresési célokat szolgál:
  while (client.available()) {
    char c = client.read();
    Serial.write(c);
  }
  // ha tíz másodperc telt el az utolsó csatlakozás óta,
  // csatlakozzon újra, és küldjön adatokat:
  if (millis() - lastConnectionTime > postingInterval) {
    httpRequest();
  }
}

// ez a metódus HTTP kapcsolatot létesít a szerverrel:
void httpRequest() {
  // új kérés küldése előtt zárjon le minden kapcsolatot.
  // Ez felszabadítja a WiFi pajzs aljzatát
  client.stop();
  // ha sikeres a kapcsolat:
  if (client.connect(server, 80)) {
    Serial.println("connecting...");
    // küldje el a HTTP PUT kérést:
    client.println("GET /latest.txt HTTP/1.1");
    client.println("Host: www.arduino.cc");
    client.println("User-Agent: ArduinoWiFi/1.1");
    client.println("Connection: close");
    client.println();
    // jegyezze meg a csatlakozás időpontját:
    lastConnectionTime = millis();
  } else {
    // ha nem tud kapcsolatot létesíteni:
    Serial.println("connection failed");
  }
}

void printWifiStatus() {
  // nyomtassa ki annak a hálózatnak az SSID-jét, amelyhez csatlakozik:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // nyomtassa ki a WiFi pajzs IP-címét:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // nyomtassa ki a vett jelerősséget:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}