Weboldal kiszolgálása a WiFi pajzsról analóg bemeneti értékekkel.
Utolsó felülvizsgálat: 2022.05.12 12:58
Ebben a példában a WiFi Shield és az Arduino kártyát fogja használni egy egyszerű webszerver létrehozásához. A WiFi könyvtár használatával eszköze képes lesz válaszolni egy HTTP-kérésre a WiFI pajzsával. Miután megnyitott egy böngészőt és navigált a WiFi pajzs IP-címére, a kártya csak annyi HTML-kóddal válaszol, hogy a böngésző megjelenítse mind a hat analóg érintkező bemeneti értékét.
Ez a példa WPA titkosítást használó hálózathoz íródott. WEP vagy nyilt hálózat esetén ennek megfelelően módosítsa a Wifi.begin() hívást.
Hardver szükséglet
Arduino WiFi pajzs
Pajzs kompatibilis Arduino kártya
(opcionális) Hat analóg érzékelő csatlakoztatva a 0-5. analóg kivezetésekhez
Az áramkör
A WiFi pajzs a 10-es, 11-es, 12-es és 13-as kivezetéseket használja a HDG104 modul SPI-csatlakozásához. A 4-es digitális kivezetés az SD-kártya chipválasztó kivezetésének vezérlésére szolgál.
Ebben a példában hozzá kell férnie egy 802.11b/g vezeték nélküli hálózathoz, amely csatlakozik az internethez. Módosítania kell a vázlaton szereplő hálózati beállításokat, hogy azok megfeleljenek az adott hálózat SSID-jének.
A WPA/WPA2 Personal titkosítást használó hálózatok esetén szüksége van az SSID-re és a jelszóra. A pajzs nem csatlakozik a WPA2 Enterprise titkosítást használó hálózatokhoz.
A WEP hálózati jelszavak kulcsként ismert hexadecimális karakterláncok. Egy WEP-hálózatnak 4 különböző kulcsa lehet; minden gombhoz hozzá van rendelve egy "Kulcsindex" érték. WEP-titkosított hálózatok esetén szüksége van az SSID-re, a kulcsra és a kulcsszámra.
A Fritzing segítségével fejlesztett kép. További áramköri példákért lásd a Fritzing projekt oldalát.
Figyelem
Ez a példa nem igényel SD-kártyát. Ha egy SD-kártya be van helyezve, de nem használja, előfordulhat, hogy a vázlat lefagy, mivel a 4-es érintkező az SD SS-jeként (aktív alacsony), és ha nem használja, akkor alapértelmezés szerint INPUT-ként van konfigurálva. Két lehetséges megoldás:
Hardver szükséglet
távolítsa el az SD-kártyát;
add hozzá ezeket a kódsorokat a setup()-hoz:
pinMode(4, OUTPUT);
digitalWrite(4, HIGH);
A kód
/*
WiFi Webszerver
Egy egyszerű webszerver, amely WiFi pajzs segítségével
mutatja meg az analóg bemeneti kivezetések értékét.
Ez a példa WPA titkosítást használó hálózathoz íródott. WEP vagy
nyilt hálózat esetén ennek megfelelően módosítsa a Wifi.begin() hívást.
Az áramkör:
* Csatolt WiFi pajzs
* Analóg bemenetek az A0-A5 kivezetésekhez csatlakoztatva (opcionális)
created 13 July 2010
by dlf (Metodo2 srl)
modified 31 May 2012
by Tom Igoe
*/
#include <SPI.h>
#include <WiFi.h>
char ssid[] = "yourNetwork"; // a hálózatának SSID-je (neve)
char pass[] = "secretPassword"; // a hálózati jelszava
int keyIndex = 0; // a hálózati kulcs indexszáma (csak a WEP-hez szükséges)
int status = WL_IDLE_STATUS;
WiFiServer server(80);
void setup() {
// Inicializálja a soros portot, és várja meg, amíg megnyílik:
Serial.begin(9600);
while (!Serial) {
; // várja meg a soros port csatlakozását. Csak a natív USB-porthoz szükséges
}
// ellenőrizze a pajzs meglétét:
if (WiFi.status() == WL_NO_SHIELD) {
Serial.println("WiFi shield not present");
// Ne folytasd:
while (true);
}
String fv = WiFi.firmwareVersion();
if (fv != "1.1.0") {
Serial.println("Please upgrade the firmware");
}
// próbáljon meg csatlakozni a Wifi hálózathoz:
while (status != WL_CONNECTED) {
Serial.print("Attempting to connect to SSID: ");
Serial.println(ssid);
// Csatlakozás WPA/WPA2 hálózathoz. Nyílt vagy WEP hálózat
// használata esetén módosítsa ezt a sort:
status = WiFi.begin(ssid, pass);
// várjon 10 másodpercet a csatlakozásra:
delay(10000);
}
server.begin();
// most csatlakozik, ezért nyomtassa ki az állapotot:
printWifiStatus();
}
void loop() {
// figyelje a bejövő ügyfeleket
WiFiClient client = server.available();
if (client) {
Serial.println("new client");
// a http kérés üres sorral végződik
bool currentLineIsBlank = true;
while (client.connected()) {
if (client.available()) {
char c = client.read();
Serial.write(c);
// ha a sor végére ért (újsor karaktert kapott) és a sor üres,
// akkor a http kérés véget ért, így választ küldhet
if (c == '\n' && currentLineIsBlank) {
if (c == '\n' && currentLineIsBlank) {
// szabványos http válaszfejlécet küld
client.println("HTTP/1.1 200 OK");
client.println("Content-Type: text/html");
client.println("Connection: close"); // a kapcsolat a válasz befejezése után megszakad
client.println("Refresh: 5"); // az oldal automatikus frissítése 5 másodpercenként
client.println();
client.println("<!DOCTYPE HTML>");
client.println("<html>");
// minden analóg bemeneti kivezetés értékét adja ki
for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
int sensorReading = analogRead(analogChannel);
client.print("analog input ");
client.print(analogChannel);
client.print(" is ");
client.print(sensorReading);
client.println("<br />");
}
client.println("</html>");
break;
}
if (c == '\n') {
// új sortt kezd
currentLineIsBlank = true;
} else if (c != '\r') {
// kapott egy karaktert az aktuális sorban
currentLineIsBlank = false;
}
}
}
// adjon időt a böngészőnek az adatok fogadására
delay(1);
// zárja le a kapcsolatot:
client.stop();
Serial.println("client disconnected");
}
}
void printWifiStatus() {
// nyomtassa ki annak a hálózatnak az SSID-jét, amelyhez csatlakozik:
Serial.print("SSID: ");
Serial.println(WiFi.SSID());
// nyomtassa ki a WiFi pajzs IP-címét:
IPAddress ip = WiFi.localIP();
Serial.print("IP Address: ");
Serial.println(ip);
// nyomtassa ki a vett jelerősséget:
long rssi = WiFi.RSSI();
Serial.print("signal strength (RSSI):");
Serial.print(rssi);
Serial.println(" dBm");
}Tudj meg többet
További alapvető oktatóanyagokat a beépített példák részben talál.
Felfedezheti a nyelvi referenciát is, az Arduino programozási nyelv részletes gyűjteményét.